mirror of
https://gitlab.cvh-server.de/skrause/flashcards.git
synced 2025-12-12 07:51:38 +01:00
54 lines
1.7 KiB
Meson
54 lines
1.7 KiB
Meson
compile_schemas = find_program('glib-compile-schemas', required : false, disabler : true)
|
|
test('Validate schema file',
|
|
compile_schemas,
|
|
args : ['--strict', '--dry-run', meson.current_source_dir()])
|
|
|
|
install_data('li.sopht.Flashcards.gschema.xml',
|
|
install_dir : get_option('datadir') / 'glib-2.0' / 'schemas'
|
|
)
|
|
|
|
desktop_file = i18n.merge_file(
|
|
input : 'li.sopht.Flashcards.desktop.in',
|
|
output : 'li.sopht.Flashcards.desktop',
|
|
type : 'desktop',
|
|
po_dir : '../po',
|
|
install : true,
|
|
install_dir : get_option('datadir') / 'applications'
|
|
)
|
|
|
|
desktop_utils = find_program('desktop-file-validate', required : false)
|
|
if desktop_utils.found()
|
|
test('Validate desktop file', desktop_utils, args : [desktop_file])
|
|
endif
|
|
|
|
appstream_file = i18n.merge_file(
|
|
input : 'li.sopht.Flashcards.metainfo.xml.in',
|
|
output : 'li.sopht.Flashcards.metainfo.xml',
|
|
po_dir : '../po',
|
|
install : true,
|
|
install_dir : get_option('datadir') / 'metainfo'
|
|
)
|
|
|
|
appstreamcli = find_program('appstreamcli', required : false, disabler : true)
|
|
test('Validate appstream file', appstreamcli,
|
|
args : ['validate', '--no-net', '--explain', appstream_file])
|
|
|
|
service_conf = configuration_data()
|
|
service_conf.set('bindir', get_option('prefix') / get_option('bindir'))
|
|
configure_file(
|
|
input : 'li.sopht.Flashcards.service.in',
|
|
output : 'li.sopht.Flashcards.service',
|
|
configuration : service_conf,
|
|
install_dir : get_option('datadir') / 'dbus-1' / 'services'
|
|
)
|
|
|
|
subdir('ui')
|
|
|
|
resources = gnome.compile_resources('resources',
|
|
'flashcards.gresource.xml',
|
|
dependencies : [blueprints, appstream_file],
|
|
c_name : 'flashcards'
|
|
)
|
|
|
|
subdir('icons')
|